Webページでの作成例(Visual Basic® Script)

RL-700S以外のプリンターをご使用の場合

  1. 1. 下記をテキストエディターで入力し、「asset.html」というファイル名で保存します。
<HTML>

<HEAD>

<TITLE>固定資産ラベル作成</TITLE>

<SCRIPT LANGUAGE="VBScript">

<!--

Sub DoPrint(strExport)

        Dim TheForm

        Set TheForm = Document.ValidForm

        'b-PACオブジェクトを生成

        Dim ObjDoc

        Set ObjDoc = CreateObject("bpac.Document")

        'P-touch Editorで作成したテンプレートファイルをオープン

        '固定資産名.lbxファイルを任意の場所に置いておく

        strDir = "LBXファイルが存在するフォルダ"

        bRet = ObjDoc.Open(strDir & "固定資産名.lbx")

        If (bRet <> False) Then   '正常にオープン?

                '「固定資産名」のテキストオブジェクトに

                '入力データを設定

                ObjDoc.GetObject("Name").Text = TheForm.FixedAsset.Value

                '「管理部門」のテキストオブジェクトに

                '入力データを設定

                ObjDoc.GetObject("Section").Text = TheForm.SectionName.Value

                '「管理No」のテキストオブジェクトに

                '入力データを設定

                ObjDoc.GetObject("Number").Text = TheForm.SectionNo.Value

                'バーコードオブジェクトに

                '入力データを設定

                ObjDoc.GetObject("QRコード1").Text = TheForm.SectionNo.Value

                '印刷を実行

                ObjDoc.StartPrint "DocumentName", bpoAutoCut

                ObjDoc.PrintOut 1, bpoAutoCut

                ObjDoc.EndPrint

                ObjDoc.Close

        End If

        'b-PACオブジェクトを解放

        Set ObjDoc = Nothing

End Sub

-->

</SCRIPT>

</HEAD>

<FORM NAME="ValidForm">

固定資産名:<INPUT VALUE="" NAME="FixedAsset" SIZE=30><BR>

管理部門:<INPUT VALUE="" NAME ="SectionName" SIZE=30><BR>

管理No:<INPUT VALUE="" NAME ="SectionNo" SIZE=30><P>

<INPUT TYPE="button" VALUE="印刷" onClick='DoPrint'>

</FORM>

</BODY>

</HTML>

補足

  • 上記中「"LBXファイルが存在するフォルダ"」部分にはlbxファイルの絶対パスを入れてください。
  • 他にイメージオブジェクトを入れ替えたり、フォント情報を設定することも可能です。
  • b-PACで使用できるメソッドは、b-PAC SDK Ver.3.0 ドキュメント(b-PACトップページよりダウンロード可能です)をご覧ください。
  1. 2. 作成した「asset.html」を表示し、各入力欄に入力後「印刷」ボタンをクリックします。
Webフォーム入力画面

P-touch Editorで作成したラベルレイアウトファイルをテンプレートにして、入力した値をラベルを印刷します。

補足

サーバーに上記ページを置き、クライアントPCにP-touchを接続して使用する場合は、次の条件である必要があります。

  • クライアントPCに下記がインストールされていること。
    • b-PACコンポーネント
    • P-touchのプリンタードライバー
    • P-touch Editorで作成したテンプレートファイル
  • クライアントPCのWebブラウザーがInternet Explore® で、ActiveXが許可されていること。

RL-700Sのプリンターをご使用の場合

  1. 1. 下記をテキストエディターで入力し、「NamePlate.html」というファイル名で保存します。
<HTML>

<HEAD>

<TITLE>ネームプレート作成</TITLE>

<SCRIPT LANGUAGE="VBScript">

<!--

Option Explicit

Const DEVICE_NAME = "Brother RL-700S"

Const ANTENNA_READER_WRITER = "Reader/Writer side"

Const ANTENNA_PRINTER = "Printer side"

Const MEMORYBANK_USERDATA = 3

Const PRINT_OPTION_AUTOCUT = &H00000001

Const PRINT_OPTION_RFID = &H20000000

'***********************************************

' ラベル印刷処理

'***********************************************

Sub DoPrint()

        Dim TheForm

        Dim objRfid

        Dim objDoc

        Set TheForm = Document.ValidForm

        Set objRfid = CreateObject("bpac.Rfid")

        Set objDoc = CreateObject("bpac.Document")

    If objRfid.Open(DEVICE_NAME) <> False Then

                If objRfid.SetActiveAntenna(ANTENNA_PRINTER) <> False Then

                        Dim strPath

                        'strPath = "LBXファイルが存在するフォルダ"

                        If objDoc.Open(strPath & "¥Name_Plate.lbl") <> False Then

                                '「Company」のテキストオブジェクトにデータを設定

                                objDoc.GetObject("company").Text = TheForm.Company.Value

                                '「Name」のテキストオブジェクトにデータを設定

                                objDoc.GetObject("name").Text = TheForm.Name.Value



                                If objRfid.WriteTagData("", MEMORYBANK_USERDATA, 0, TheForm.Name.Value) <> False Then

                                        '印刷を実行

                                        Dim printOption

                                        printOption = (PRINT_OPTION_AUTOCUT Or PRINT_OPTION_RFID)

                                        objDoc.StartPrint "DocumentName", printOption

                                        objDoc.PrintOut 1, printOption

                                        objDoc.EndPrint

                                Else

                                        MsgBox "書き込み失敗"

                                End If

                        Else

                                MsgBox "ファイルオープン失敗"

                        End If

                Else

                        MsgBox "アンテナ設定失敗"

                End If

        Else

                MsgBox "デバイスオープン失敗"

        End If



        objDoc.Close

        objRfid.Close

        Set objDoc = Nothing

        Set objRfid = Nothing

End Sub



'***********************************************

' RFIDタグ書き込み処理

'***********************************************

Sub DoWrite()

        Dim TheForm

        Dim objRfid

        Set objRfid = CreateObject("bpac.Rfid")

        Set TheForm = Document.ValidForm

        If objRfid.Open(DEVICE_NAME) <> False Then

                If objRfid.SetActiveAntenna(ANTENNA_READER_WRITER) <> False Then

                        '選択した行の「氏名」をセット

                        Dim strCell

                        strCell = TheForm.Name.Value

                        'UIDの読み取り

                        Dim arrTagId

                        arrTagId = objRfid.ReadTagId()

                        If objRfid.ErrorCode = 0 Then

                                'データの書き込み

                                If objRfid.WriteTagData(arrTagId(0), MEMORYBANK_USERDATA, 0, strCell) <> False Then

                                        MsgBox ("書き込み終了" & Chr(13) & strCell)

                                Else

                                        MsgBox "書き込み失敗"

                                End If

                        Else

                                MsgBox "タグ読み取り失敗"

                        End If

        Else

                        MsgBox "アンテナ設定失敗"

                End If

        Else

                MsgBox "デバイスオープン失敗"

        End If

        objRfid.Close

        Set objRfid = Nothing   'b-PACオブジェクトを解放

End Sub



'***********************************************

' RFIDタグ読み取り処理

'***********************************************

Sub DoRead()

    Dim objRfid

    Set objRfid = CreateObject("bpac.Rfid")



    If objRfid.Open(DEVICE_NAME) <> False Then

        If objRfid.SetActiveAntenna(ANTENNA_READER_WRITER) <> False Then

                'UIDの読み取り

                        Dim arrTagId

                        arrTagId = objRfid.ReadTagId()

                        If objRfid.ErrorCode = 0 Then

                                'データの書き込み

                                Dim dataSize

                                dataSize = objRfid.GetBlockSize(arrTagId(0), MEMORYBANK_USERDATA) * objRfid.GetNumberOfBlocks(arrTagId(0), MEMORYBANK_USERDATA)

                                Dim strUserdata

                                strUserdata = objRfid.ReadTagData(arrTagId(0), MEMORYBANK_USERDATA, 0, dataSize)

                                If objRfid.ErrorCode = 0 Then

                                        MsgBox ("読み取り終了" & Chr(13) & strUserdata)

                                Else

                                        MsgBox "読み取り失敗"

                                End If

                    Else

                                MsgBox "タグ読み取り失敗"

                    End If

            Else

                        MsgBox "アンテナ設定失敗"

                End If

        Else

                MsgBox "デバイスオープン失敗"

        End If

        objRfid.Close

        Set objRfid = Nothing   'b-PACオブジェクトを解放

End Sub

-->

</SCRIPT>

</HEAD>

<FORM NAME="ValidForm">

会社名:<INPUT VALUE="" NAME="Company" SIZE=30><BR>

氏名:<INPUT VALUE="必ず入力してください" NAME ="Name" SIZE=30><P>

<INPUT TYPE="button" VALUE="ラベル印刷" onClick='DoPrint'>

<INPUT TYPE="button" VALUE="Write" onClick='DoWrite'>

<INPUT TYPE="button" VALUE="Read" onClick='DoRead'>

</FORM>

</BODY>

</HTML>

補足

RL-700S SDKで使用できるメソッドは、b-PAC SDK Ver.3.0 ドキュメント(b-PACトップページよりダウンロード可能です)をご覧ください。

  1. 2. 作成した「NamePlate.html」を表示し、各入力欄に入力後、「ラベル印刷」ボタンをクリックします。
Webフォーム入力画面
「ラベル印刷」ボタン P-touch Editorで作成したラベルレイアウトファイルをテンプレートにして、入力した値をラベルを印刷します。RFIDタグには「氏名」を書き込みます。
「Write」ボタン 「氏名」でRFIDタグの内容を書き換えます。
「Read」ボタン RFIDタグの内容を読み込みます。

補足

サーバーに上記ページを置き、クライアントPCにP-touchを接続して使用する場合は、次の条件である必要があります。

  • クライアントPCに下記がインストールされていること。
    • RL-700S SDK
    • P-touchのプリンタードライバー
    • P-touch Editorで作成したテンプレートファイル
  • クライアントPCのWebブラウザーがInternet Explore® で、ActiveXが許可されていること。

ラベルプリンター 導入事例

ピンゴルフジャパン株式会社様
ピンゴルフジャパン株式会社様
  • 作業効率改善
  • 飲食・小売
  • 従業員数70名
株式会社福山臨床検査センター様
株式会社福山臨床検査センター様
  • 作業効率改善
  • 医療・福祉
  • 従業員数389名

小規模オフィス、営業所、店舗、学校、工場、ホテルなどでの導入事例をご紹介

ご購入を検討中のお客様へ

ご利用中のお客様へ(サポート)

開発をご検討中のお客様へ

スペシャルサイト

このページをシェアする